Différences

Ci-dessous, les différences entre deux révisions de la page.

--- siprojuris:enrichir_les_donnes_avec_lod [2018/05/27 23:28]
Francesco Beretta créée
+++ siprojuris:enrichir_les_donnes_avec_lod [2018/12/28 20:34]
Francesco Beretta [Pour trouver la biblio, inverser le triplet]
@@ Ligne 6: / Ligne 6: @@
-==== Remarque générale ====
+===== Remarque générale =====
+L'alignement des données du projet SIPROJURIS, effectué pour trois quarts des acteurs (431 sur 567 professeurs) et en cours pour les autres, permet d'accéder à plusieurs ressources publiées dans les LOD, dont les catalogues du SUDOC et BNF, Wikipedia et DBPedia, Wikidata, etc.
+L'objectif de cette partie du défi est d'enrichir la population SIPROJURIS tant en l'élargissant qu'en collectant de nouvelles informations concernant les acteurs de la population et en les transformant en utilisant l'ontologie symogih.org (ou toute autre ontologie opportune) afin de pouvoir les intérroger et analyser dans leur ensemble.
+Si souhaité, les nouvelles données ainsi transformées peuvent être envoyées aux organisateurs du défi (respectivement à Francesco Beretta) au format XML ou ttl, tout en les assortissant de métadonnées et d'une indication de licence explicite. Elles pourront alors être publiées dans un graphe supplémentaire du point d'accès SPARQL.
+===== Un exemple : Gaston,Louis, Henry May (1849 - 1940) =====
+ATTENTION : requêtes à exécuter sur le [[http://bhp-publi.ish-lyon.cnrs.fr:8888/sparql|point d'accès SPARQL du projet //symogih.org//]]
+==== Son parcours biographique  ====
+<code sparql>
+SELECT ?TyRoLabel ?infoStandardDate ?infoStandardLabel ?TyInLabel
+WHERE
+    {GRAPH <http://symogih.org/graph/symogih-kute>
+        {
+        ?tyro rdfs:label ?TyRoLabel.
+        ?tyin rdfs:label ?TyInLabel.
+        {GRAPH <http://symogih.org/graph/siprojuris-sym>
+            {?s ?p syr:Actr56241;
+            sym:isComponentOf ?info;
+            sym:hasRoleType ?tyro.
+            ?info sym:knowledgeUnitStandardLabel ?infoStandardLabel;
+                     sym:knowledgeUnitStandardDate ?infoStandardDate;
+                     sym:hasKnowledgeUnitType ?tyin.
+            }
+            }
+        }
+    }
+ORDER BY ?infoStandardDate
+</code>
+==== Les données IdRef le concernant ====
+<code sparql>
+SELECT ?idRef  ?p ?o
+WHERE
+{
+GRAPH <http://symogih.org/graph/siprojuris-sym>
+            {syr:Actr56241 owl:sameAs ?idRef.
+            }
+SERVICE <https://data.idref.fr/sparql>
+  { ?idRef ?p ?o.
+  }
+}
+</code>
+==== Pour trouver la biblio, inverser le triplet ====
+Une question intéressante en termes de TALN et d'analyse de données: typologie des publications en fonctions de l'évolution de la carrière.
+<code sparql>
+SELECT ?s ?o
+WHERE
+{
+{GRAPH <http://symogih.org/graph/siprojuris-sym>
+            {syr:Actr56241 owl:sameAs ?idRef.
+            }
+         }
+SERVICE <https://data.idref.fr/sparql>
+   { ?s ?p ?idRef;
+     <http://purl.org/dc/terms/bibliographicCitation> ?o}
+}
+</code>
+===== Interroger l'ensemble des données =====
+ATTENTION: le requêtes suivantes sont à exécuter sur le //[[https://data.idref.fr/sparql|point d'accès SPARQL des IdRef]]//.
+==== Retrouver toutes les ressources liées ====
+<code sparql>
+SELECT *
+WHERE {
+SERVICE <http://bhp-publi.ish-lyon.cnrs.fr:8888/sparql>
+{
+GRAPH <http://symogih.org/graph/siprojuris-sym>
+{
+?s owl:sameAs ?o.
+}
+}
+}
+</code>
+==== Trouver les URIs des ressources liées à travers les IdRef ====
+A exécuter sur le //[[https://data.idref.fr/sparql|point d'accès SPARQL des IdRef]]//
+<code sparql>
+SELECT *
+WHERE {
+{
+SERVICE <http://bhp-publi.ish-lyon.cnrs.fr:8888/sparql>
+{SELECT *
+WHERE {
+GRAPH <http://symogih.org/graph/siprojuris-sym>
+{
+?s owl:sameAs ?idref.
+}
+}
+}
+?idref owl:sameAs ?url.
+}
+}
+</code>
+==== Interroger la BNF ====
+=== Effectif des notices d'autorité disponibles  ===
+A exécuter sur le //[[https://data.idref.fr/sparql|point d'accès SPARQL des IdRef]]//
+<code sparql>
+SELECT count(*)
+WHERE {
+{
+SERVICE <http://bhp-publi.ish-lyon.cnrs.fr:8888/sparql>
+{SELECT *
+WHERE {
+GRAPH <http://symogih.org/graph/siprojuris-sym>
+{
+?s owl:sameAs ?idref.
+}
+}
+}
+?idref owl:sameAs ?url.
+FILTER ( CONTAINS(str(?url), "bnf"))
+}
+}
+</code>
+=== Les informations qu'elles contiennent ===
+A exécuter sur le //[[https://data.idref.fr/sparql|point d'accès SPARQL des IdRef]]//
+<code sparql>
+SELECT *
+WHERE {
+{
+SERVICE <http://bhp-publi.ish-lyon.cnrs.fr:8888/sparql>
+{SELECT *
+WHERE {
+GRAPH <http://symogih.org/graph/siprojuris-sym>
+{
+?s owl:sameAs ?idref.
+}
+}
+}
+}
+?idref owl:sameAs ?uri.
+BIND (uri(replace(str(?uri), 'foaf:Person', 'about')) as ?new_uri)
+{
+SERVICE <http://data.bnf.fr/sparql>
+{
+SELECT *
+WHERE {
+?new_uri ?pb ?ob
+}
+}
+}
+}
+</code>
+===== Elargir le corpus avec les données de la BNF =====
+==== Retenir uniquement les notices biographiques de la BNF ====
+A exécuter sur le //[[https://data.idref.fr/sparql|point d'accès SPARQL des IdRef]]//
+<code sparql>
+SELECT *
+WHERE {
+{
+SERVICE <http://bhp-publi.ish-lyon.cnrs.fr:8888/sparql>
+{SELECT *
+WHERE {
+GRAPH <http://symogih.org/graph/siprojuris-sym>
+{
+?s owl:sameAs ?idref.
+}
+}
+}
+}
+?idref owl:sameAs ?uri.
+BIND (uri(replace(str(?uri), 'foaf:Person', 'about')) as ?new_uri)
+{
+SERVICE <http://data.bnf.fr/sparql>
+{
+SELECT *
+WHERE {
+?new_uri <http://rdvocab.info/ElementsGr2/biographicalInformation> ?ob
+}
+}
+}
+}
+</code>
+==== Obtenir les données concernant des acteurs similaires ====
+ATTENTION: le requêtes suivantes sont à exécuter sur le //[[http://data.bnf.fr/sparq|point d'accès SPARQL de la BNF]]//.
+Chercher les acteurs dont le vocabulaire des notices est proche de celui de la population de départ
+<code sparql>
+PREFIX  egr:  <http://rdvocab.info/ElementsGr2/>
+SELECT DISTINCT  ?s ?na ?fn ?annee ?pb ?gd ?bio
+WHERE
+  { { { SELECT DISTINCT  ?s ?bio
+        WHERE
+          {   { ?s egr:biographicalInformation ?bio
+            FILTER (( CONTAINS(?bio, "droit") || CONTAINS(?bio, "Droit") )  && ( CONTAINS(?bio, "faculté") || CONTAINS(?bio, "Faculté") )  )
+              }
+            UNION
+              { ?s egr:biographicalInformation ?bio
+            FILTER (( CONTAINS(?bio, "droit") || CONTAINS(?bio, "Droit") )  && ( CONTAINS(?bio, "professeur") || CONTAINS(?bio, "Professeur") )  )
+        }
+            UNION
+              { ?s egr:biographicalInformation ?bio
+            FILTER (( CONTAINS(?bio, "juriste") || CONTAINS(?bio, "Juriste") )  && ( CONTAINS(?bio, "professeur") || CONTAINS(?bio, "Professeur") )  )
+            }
+          }
+      }
+      ?s egr:dateOfBirth ?bd
+      OPTIONAL
+        { ?s <http://xmlns.com/foaf/0.1/name> ?na }
+      OPTIONAL
+        { ?s <http://xmlns.com/foaf/0.1/familyName> ?fn }
+      OPTIONAL
+        { ?s egr:placeOfBirth ?pb }
+      OPTIONAL
+        { ?s <http://xmlns.com/foaf/0.1/gender> ?gd }
+    }
+    BIND(STRBEFORE(STRAFTER(STR(?bd), "http://data.bnf.fr/date/"), "/") AS ?annee)
+    FILTER ( ( ?annee > "1791" ) )
+  }
+ORDER BY ?annee
+</code>

Wiki de l'ARHNAxe de recherche en histoire numériqueLARHRA UMR5190

Outils pour utilisateurs

Outils du site

Différences

Outils de la page

Wiki de l'ARHN

Axe de recherche en histoire numérique
LARHRA UMR5190